Excel电子表格如何提取word中的数据？

1、      首先按照实际工作需要制作好Word表格。如下图。

2、     然后调出开发者工具。可以点击文件—选项—自定义功能区，右侧勾选“开发工具”即可。

3、      表格制作完成后修改需要填写信息的单元格,也就是以后需要提取的单元格，切换到开发模式选项卡，点击“Aa”格式文本内容控件，接下来单击信息框,然后在开发工具中点选“设计模式”。

4、      然后打开属性，在对话框输入标题，这就是信息框的信息提示文字，要是有需求，还可以修改边框颜色、文本样式等等。

5、    把所有需要填写信息的单元格都按照上述步骤操作完毕，点击开发模式中的“限制编辑”，在Word右侧栏中，勾选“限制对选定的样式设置格式”和“仅允许在文档中进行此类型的修改”并选中“填写窗体”。

6、    到此第一部分word设置完成，接下来，我们设置Excel。

   同样是切换到开发工具选项卡，点选最左侧的“Visual Basic”

7、双击Sheet1，把以下代码复制

Option Base 1

Sub readDoc()

Dim WordApp As Word.Application

Set WordApp = CreateObject("Word.Application")

Dim WordDoc As Word.Document

Dim diag1 As FileDialog

Dim return1 As String

Dim filePathArray()

Set diag1 = Application.FileDialog(msoFileDialogFilePicker)

'定义文件选择对话框

With diag1

.AllowMultiSelect = True '设置文件选择对话框能够选择多个文件

return1 = .Show '打开文件选择对话框

n = .SelectedItems.Count '将选中文件个数保存至变量n

If return1 = -1 Then

'如选中文件(retun1=-1)则将选中的文件路径保存到filePathArray数组

ReDim filePathArray(n)

For i = 1 To n

filePathArray(i) = .SelectedItems(i)

Next

Else '如果未选中任何文件则提示

MsgBox "未选择任何文件", vbExclamation

End If

End With

For j = 1 To n

Set WordDoc = WordApp.Documents.Open(filePathArray(j))

'根据filePathArray数组中的路径逐个打开Word文件

Dim ccSet

Set ccSet = WordDoc.ContentControls

'将ccSet设为打开文档的内容控件集合

i = 1

For Each cc In ccSet '遍历所有内容控件

Application.ActiveSheet.Cells(j, i) = cc.Range.Text '将内容控件内容保存至单元格

i = i + 1

Next

WordDoc.Close '关闭当前Word文档

Next

WordApp.Quit

End Sub

8、   接着继续点选当前Visual Basic界面上方工具栏的“工具—引用”，在“可使用的引用”中找到“Microsoft Word 16.0 Object Library”并勾选确定。

9、      返回到Excel主界面，还是在开发工具选项卡中，点击“宏”，选中刚才编辑的这个宏命令，单击“运行”，这时Excel会自动弹出文件选择框，找到要摘录信息的Word文档点选打开，Excel就可以开始自动摘录信息了。这样一来，数据摘录的工作就完全依靠电脑自动完成了，大大节省了工作时间，也避免了手工摘录的出错几率。

10、     到此，全部设置完成，当收集信息时，就可以把word表格分发给多人，然后统一通过Excel来自动完成，省时高效。