如何用批处理文件（.bat）实现笔记本WiFi共享
1、首先新建一个文本文件，也就是txt文件。命名为wifi.txt，名字随意取。然后用记事本打开，编辑文件
2、在第一行写下如下代码：
@echo off
title wifi共享 bat版
其中@echo off的作用是关闭回显，也就是在使用的时候不显示命令本身
第二行是设置标题
这里echo大小写都行
3、然后继续写下列代码
:start
CLS
COLOR 3f
MODE con: COLS=42 LINES=28
ECHO.
ECHO ┏━━━━━━━━━━━━━━━┓
ECHO ┃请选择要进行的操作，然后按回车┃
ECHO ┗━━━━━━━━━━━━━━━┛
ECHO.
ECHO 1. 开启热点
ECHO ──────
ECHO 2. 发射信号
ECHO ──────
ECHO 3. 关闭信号
ECHO ──────
ECHO 4. 关闭热点
ECHO ──────
ECHO 5. 重置密码
ECHO ──────
ECHO 6. 重置名称
ECHO ──────
ECHO 7. 网络信息
ECHO ──────
ECHO 8. 使用帮助
ECHO ──────
ECHO 9. 懒人设置
ECHO ──────
ECHO 0. 退出程序
ECHO ──────
这里代码的作用就是设置一个显示界面而已
4、继续添加代码
:ch
SET Choice=
SET /P Choice=选择操作并回车:
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
ECHO.
IF /I "%Choice%"=="1" GOTO 1
IF /I "%Choice%"=="2" GOTO 2
IF /I "%Choice%"=="3" GOTO 3
IF /I "%Choice%"=="4" GOTO 4
IF /I "%Choice%"=="5" GOTO 5
IF /I "%Choice%"=="6" GOTO 6
IF /I "%Choice%"=="7" GOTO 7
IF /I "%Choice%"=="8" GOTO 8
IF /I "%Choice%"=="9" GOTO moren
IF /I "%Choice%"=="0" GOTO end
ECHO 选择无效，请重新输入
ECHO.
GOTO ch
这里代码实现的选择功能
下面就一次性把所有代码贴出来，要用的直接复制粘贴就可（不要复制之前的这片段代码）
5、@ECHO off
TITLE wifi共享 bat版
:start
CLS
COLOR 3f
MODE con: COLS=42 LINES=28
ECHO.
ECHO ┏━━━━━━━━━━━━━━━┓
ECHO ┃请选择要进行的操作，然后按回车┃
ECHO ┗━━━━━━━━━━━━━━━┛
ECHO.
ECHO 1. 开启热点
ECHO ──────
ECHO 2. 发射信号
ECHO ──────
ECHO 3. 关闭信号
ECHO ──────
ECHO 4. 关闭热点
ECHO ──────
ECHO 5. 重置密码
ECHO ──────
ECHO 6. 重置名称
ECHO ──────
ECHO 7. 网络信息
ECHO ──────
ECHO 8. 使用帮助
ECHO ──────
ECHO 9. 懒人设置
ECHO ──────
ECHO 0. 退出程序
ECHO ──────
:ch
SET Choice=
SET /P Choice=选择操作并回车:
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
ECHO.
IF /I "%Choice%"=="1" GOTO 1
IF /I "%Choice%"=="2" GOTO 2
IF /I "%Choice%"=="3" GOTO 3
IF /I "%Choice%"=="4" GOTO 4
IF /I "%Choice%"=="5" GOTO 5
IF /I "%Choice%"=="6" GOTO 6
IF /I "%Choice%"=="7" GOTO 7
IF /I "%Choice%"=="8" GOTO 8
IF /I "%Choice%"=="9" GOTO moren
IF /I "%Choice%"=="0" GOTO end
ECHO 选择无效，请重新输入
ECHO.
GOTO ch
:1
:: 开启热点
CLS
COLOR 3f
MODE con: COLS=50 LINES=25
ECHO.
ECHO ┏━━━━━━━━━┓
ECHO ┃ 继续设置请按 1 ┃
ECHO ┃ 返回菜单请按 2 ┃
ECHO ┗━━━━━━━━━┛
Set /p ask=选择:
ECHO.
if /i "%ask%"=="1" goto SHE
if /i "%ask%"=="2" goto start
:SHE
ECHO.
netsh wlan set hostednetwork mode=allow
ECHO.
ECHO ┏━━━━━━━━┓
ECHO ┃ 请设置热点名称 ┃
ECHO ┗━━━━━━━━┛
ECHO.
set /p Ming=请设置名称：
netsh wlan set hostednetwork ssid=%Ming%
ECHO.
ECHO ┏━━━━━━━━┓
ECHO ┃ 请设置热点密码 ┃
ECHO ┗━━━━━━━━┛
ECHO.
set /p Mima=请设置8位以上的密码：
netsh wlan set hostednetwork key=%Mima%
::是否发射信号
CLS
COLOR 3f
MODE con: COLS=41 LINES=22
ECHO.
ECHO ┏━━━━━━━━━━━━━┓
ECHO ┃ 您现在是否要发射信号 ┃
ECHO ┃ 确认请按 1 ┃
ECHO ┃ 暂时不发射请按 2 返回菜单┃
ECHO ┗━━━━━━━━━━━━━┛
ECHO.
Set /p ask=选择:
ECHO.
if /i "%ask%"=="1" goto 2
if /i "%ask%"=="2" goto start
:2
::发射信号
CLS
COLOR 3f
MODE con: COLS=41 LINES=22
netsh wlan start hostednetwork
ECHO.
ECHO ┏━━━━━━━━━━━━━┓
ECHO ┃ 已发射信号，按任意键返回 ┃
ECHO ┗━━━━━━━━━━━━━┛
ECHO.
PAUSE >NUL
GOTO start
:3
::关闭信号
CLS
netsh wlan stop hostednetwork
ECHO.
ECHO ┏━━━━━━━━━━━━━━━┓
ECHO ┃ 已关闭发射信号，按任意键返回 ┃
ECHO ┗━━━━━━━━━━━━━━━┛
ECHO.
PAUSE >NUL
GOTO start
:4
::关闭热点
CLS
netsh wlan set hostednetwork mode=disallow
ECHO.
ECHO ┏━━━━━━━━━━━━━━┓
ECHO ┃ 已关闭热点，请按任意键返回 ┃
ECHO ┗━━━━━━━━━━━━━━┛
ECHO.
PAUSE >NUL
GOTO start
:5
:: 重置密码
CLS
ECHO.
ECHO ┏━━━━━━━━┓
ECHO ┃ 请重置热点密码 ┃
ECHO ┗━━━━━━━━┛
ECHO.
set /p ChongMi=请重置8位以上的密码：
netsh wlan set hostednetwork key=%ChongMi%
ECHO.
ECHO ┏━━━━━━━━━━━━━━━━┓
ECHO ┃ 已重置热点密码，请按任意键返回 ┃
ECHO ┗━━━━━━━━━━━━━━━━┛
ECHO.
PAUSE >NUL
GOTO start
:6
:: 重置名称
CLS
ECHO.
ECHO ┏━━━━━━━━┓
ECHO ┃ 请重置热点名称 ┃
ECHO ┗━━━━━━━━┛
ECHO.
set /p ZhongMing=请设置名称：
netsh wlan set hostednetwork ssid=%ZhongMing%
netsh wlan start hostednetwork
ECHO.
ECHO ┏━━━━━━━━━━━━━━━━┓
ECHO ┃ 已重置热点名称，请按任意键返回 ┃
ECHO ┗━━━━━━━━━━━━━━━━┛
ECHO.
PAUSE >NUL
GOTO start
:7
::网络信息显示
CLS
COLOR 3f
MODE con: COLS=47 LINES=26
ECHO.
ECHO ┏━━━━━━━━┓
ECHO ┃ 网络信息显示 ┃
ECHO ┗━━━━━━━━┛
ECHO.
netsh wlan show hostednetwork
ECHO -----------------------
ECHO.
PAUSE
GOTO start
:moren
cls
::如果你不想每次都进入第一步设置名称密码等，可以用自己设置好的，以下参数可以自
己改
::修改以下两行即可，两行其中ssid为热点名称；key为密码
set ssid=wifi-share
set /a key=20152015
netsh wlan set hostednetwork mode=allow ssid=%ssid% key=%key%
ECHO.
ECHO.
ECHO.
ECHO ━━━━━━━━━━━━━━━━━━━━
ECHO 热点默认名称为: %ssid%
ECHO 热点默认密码为: %key%
ECHO ━━━━━━━━━━━━━━━━━━━━
ECHO.
netsh wlan start hostednetwork
pause
goto start
:8
::使用说明
CLS
COLOR 3f
MODE con: COLS=69 LINES=33
ECHO.
ECHO ┏━━━━━━━━━━━━┓
ECHO ┃ 使 用 说 明 ┃
ECHO ┗━━━━━━━━━━━━┛
ECHO.
ECHO -------------------------------------------------------------------
ECHO 1.使用此程序前请设置好计算机网络共享！此程序在windows7系统下测试
ECHO 可用。电脑需配置有无线网卡，并支持承载网络，否则无法使用本程序
ECHO -------------------------------------------------------------------
ECHO 2.每次使用都需要设置第1或第9步，为热点设置名称和密码，并发射即可！
ECHO -------------------------------------------------------------------
ECHO 3.名称建议用字母和数字，请尽量不用复杂的符号，否则系统可能不识别
ECHO -------------------------------------------------------------------
ECHO 4.密码请设置8位数以上，请尽量不用复杂的符号， 否则系统可能不识别
ECHO -------------------------------------------------------------------
ECHO 5.若出现搜索到信号但是连接不了或上不了网的情况，那么重新设置第1步
ECHO -------------------------------------------------------------------
ECHO 6.第3、4步区别：第3步为“已停止承载网络”，若进入信息显示会看到
ECHO “承载网络状态”为未启用；第4步为“承载网络模式已设置为禁止”
ECHO 进入信息显示会看到“承载网络状态”为不可用。不用热点的时候选择
ECHO 第3或第4步都可。若之后想继续使用无线发射，需再次设置第1或第9步
ECHO -------------------------------------------------------------------
ECHO 7.如果不想每次进入第1步设置名称和密码，则可以进入第9步，一键设置
ECHO 即可发射热点。默认名称为WIFI，密码为1234567890；若想更改默认名
ECHO 称及密码，可进入代码中的:moren修改其中两行即可（代码有修改说明）
ECHO -------------------------------------------------------------------
ECHO 8.计算机关机也会自动关闭无线热点，故启动电脑后若想使用无线发射，
ECHO 需再次设置第1步。如需要更改密码或名称，可在主菜单选择第5步或第
ECHO 6步进行更改，然后在接收设备上重新连接即可。
ECHO -------------------------------------------------------------------
ECHO.
ECHO 请按任意键返回主菜单...
PAUSE >NUL
GOTO start
:end
Exit
6、保存文件，然后重命名为wifi.bat文件，或另存为wifi.bat文件。
直接右键以管理员权限运行即可